nikola-wan
Veteran Member
While helping the vintagetek museum in Oregon repair their Tektronix 4054A with Option 31 Color Dynamic Graphics CRT and Option 30 Dynamic Graphics coprocessor - they shared a NEW Instant Art BASIC program for Tektronix 4050 computers designed by one of their volunteers John Ollis for the STEM program they will be participating in this week.
John Ollis asks that you keep his name in the program as attribution.
Instant Art is intended to show off Tektronix 4050 vector graphics and be simple enough for younglings or adults to enjoy.
You simply type your name or other text (case sensitive) and the program draws a graphic shape.
First attachment shows the Instant Art graphic of WILMA in all capital letters.
Second attachment show the graphic with wilma in lower case letters.
Here is Abracadabra:
Lots of fun!
Here is the INSTANT ART program listing:
All the screenshots are from the latest Tektronix 4051 Emulator. Files and instructions are here:
https://github.com/mmcgraw74/Tektronix-4051-Emulator
If you are near Oregon - you should plan to visit the vintagetek museum - information in this link:
https://vintagetek.org
John Ollis asks that you keep his name in the program as attribution.
Instant Art is intended to show off Tektronix 4050 vector graphics and be simple enough for younglings or adults to enjoy.
You simply type your name or other text (case sensitive) and the program draws a graphic shape.
First attachment shows the Instant Art graphic of WILMA in all capital letters.
Second attachment show the graphic with wilma in lower case letters.
Here is Abracadabra:
Lots of fun!
Here is the INSTANT ART program listing:
Code:
100 REM INSTANT ART
110 REM WRITTEN BY JOHN OLLIS FOR THE VINTAGETEK MUSEUM
200 WINDOW 0,4096,0,3072
210 D0=4870735
220 PAGE
230 DEF FNA(X)=INT(X-INT(X/16)*16)
500 DIM S(1000)
510 PRINT "LOADING TABLE (ABOUT 30 SEC)"
520 S1=2*PI/1000
530 FOR I=1 TO 250
540 V=SIN(I*S1)
550 S(I)=V
560 S(501-I)=V
570 S(500+I)=-V
580 S(1001-I)=-V
590 NEXT I
990 PAGE
1000 MOVE 0,2900
1010 PRINT "TYPE YOUR NAME OR OTHER TEXT FOLLOWED BY RETURN"
1020 INPUT D$
1030 L=LEN(D$)
1040 IF L=0 THEN 990
1050 PAGE
1070 D=D0
1080 FOR I=1 TO L
1090 IF D<>0 THEN 1110
1100 D=D0
1110 E$=SEG(D$,I,1)
1120 D1=ASC(E$)
1170 D=D*D1
1180 D=INT(D*16+D/1.6777216E+7)
1190 D=D-INT(D/1.6777216E+7)*1.6777216E+7
1200 NEXT I
1520 V1=FNA(D)
1530 V2=FNA(D/16)
1540 V3=FNA(D/256)
1550 V4=FNA(D/4096)
1560 V5=FNA(D/65536)
2010 IF V1<>0 THEN 2030
2020 V1=15
2030 S3=INT(V1/8)
2040 V1=V1-S3*8
2050 S2=INT(V1/4)
2060 V1=V1-S2*4
2070 S1=INT(V1/2)
2080 S0=V1-S1*2
2100 Z=V2/4+4
2110 R3=INT(V3*0.0175*1000/PI)
2120 R2=INT(V4*0.0011*Z*1000/PI)
2130 R1=INT(V5*0.0011*Z*1000/PI)
2140 A1=250
2150 A2=250
2160 A4=500/4
2170 A3=250+A4
2180 PRINT D$
3000 Z=Z*4
3005 R=1400
3010 C1=S(A1)
3020 C2=S(A2)
3030 C3=S(A3)
3040 S3=S(A4)
3050 M1=R*C3*C2
3060 M2=R*S3*C2
3070 M3=R*S3*C1
3080 M4=R*C3*C1
3100 MOVE 2048+M1,1536-M2
3110 IF S0=0 THEN 3140
3120 DRAW 2048-M3,1536-M4
3130 GO TO 3150
3140 MOVE 2048-M3,1536-M4
3150 IF S1=0 THEN 3180
3160 DRAW 2048-M1,1536+M2
3170 GO TO 3190
3180 MOVE 2048-M1,1536+M2
3190 IF S2=0 THEN 3210
3200 DRAW 2048+M3,1536+M4
3210 IF S3=0 THEN 3300
3220 DRAW 2048+M1,1536-M2
3300 A1=A1+R1
3310 IF A1<1001 THEN 3330
3320 A1=A1-1000
3330 A2=A2+R2
3340 IF A2<1001 THEN 3360
3350 A2=A2-1000
3360 A3=A3+R3
3370 IF A3<1001 THEN 3390
3380 A3=A3-1000
3390 A4=A4+R3
3400 IF A4<1001 THEN 3420
3410 A4=A4-1000
3420 R=R-Z
3440 IF R>0 THEN 3010
3450 GO TO 1000All the screenshots are from the latest Tektronix 4051 Emulator. Files and instructions are here:
https://github.com/mmcgraw74/Tektronix-4051-Emulator
If you are near Oregon - you should plan to visit the vintagetek museum - information in this link:
https://vintagetek.org
Last edited: