Dear all!
As this is my first PDP-11 - I would like to kindly ask for some advice which software / Operating system will work and what is worth trying?
Which Operating system does make sense? RT-11 or something else?
Is except from a BASIC interpreter some other languages (Pascal/Fortran compilers) working?
What text editor can you recommend?
Is there maybe a graphics package using Sixel/Regis graphics?
Is it worth looking for some h/w extensions (like a 11/23 board, additional memory?)
Best regards
Stephan
Stephan,
I run RT-11 SJ on a PDP-11/05 with 28KW that is roughly similar in CPU capabilities. Basic-11 is the
best for interactive programming. The LENGTH command will tell you how much free space you have left
in Basic.
I can compile Fortran IV programs but I have to turn off the command line editing to get enough free memory for that.
KED works great if you have a fully VT100 compatible terminal (and keyboard).
You mentioned REGIS graphics and if you have a REGIS compatible terminal you can do a lot with just sending RGL
commands via Basic-11. Below is a sample program to plot data from a text file.
An 11/23 is a great CPU board and I would highly recommend trying to get one, ideally with the FPP microcode chip.
Best,
Mark
P.S. in Line 120 below @: P should not have a space. This Forum keeps changing the @: P
with no space into an Emoji @
10 REM REGIS PLOTTING PROGRAM
20 DIM X(30),Y(30) \ N%=0
30 PRINT "Input name of data file: "; \ INPUT F$
40 OPEN F$ FOR INPUT AS FILE #1
50 LINPUT #1,T$ \ LINPUT #1,X$ \ LINPUT #1,Y$
60 INPUT #1,X1,X2,X3,Y1,Y2,Y3
70 N%=N%+1 \ INPUT #1,X(N%),Y(N%)
80 IF END #1 THEN PRINT "END-OF-FILE" \ GO TO 100
90 GO TO 70
100 X4=(700-100)/(X2-X1) \ Y4=-1*(400-80)/(Y2-Y1)
110 E$=CHR$(27) \ PRINT E$;"P2p S(E)"
120 PRINT "@: P V[,+5] V[,-10] V[,+5] V[+5,] V[-10,] V[+5,] @;"
130 PRINT "@:T V[,+10] V[,-10] @;"
140 PRINT "@:H V[-10,] V[+10,] @;"
150 PRINT "P[100,80] V[100,400] V[700,400] V[700,80] V[100,80]"
160 X%=INT(X(1)*X4+100)
170 Y%=INT(Y(1)*Y4+400)
180 PRINT USING "P[### , ###] @P",X%,Y%
190 FOR I%=2 TO N%
200 X%=INT(X(I%)*X4+100)
210 Y%=INT(Y(I%)*Y4+400)
220 PRINT USING "V[### , ###] @P",X%,Y%
230 NEXT I%
240 X5=(X2-X1)/X3 \ Y%=400
250 FOR I%=1 TO X3
260 X6=I%*X5+X1
270 X%=INT(X6*X4+100)
280 PRINT USING "P[### , ###] @T",X%,Y%
290 PRINT "P[-20,+20]T(D0,S1,D0)'";X6;"'"
300 NEXT I%
310 Y5=(Y2-Y1)/Y3 \ X%=100
320 FOR I%=1 TO Y3
330 Y6=I%*Y5+Y1
340 Y%=INT(Y6*Y4+400)
350 PRINT USING "P[### , ###] @H",X%,Y%
360 PRINT "P[-50,-10]T(D0,S1,D0)'";Y6;"'"
370 NEXT I%
380 PRINT "P[300,50]T(D0,S2,D0)'";T$;"'"
390 PRINT "P[350,450]T(D0,S1,D0)'";X$;"'"
400 PRINT "P[50,200]T(D-90,S1,D-90)'";Y$;"'"
410 PRINT "P[700,400]"
500 S1=0 \ S2=0 \ S3=0 \ T1=0 \ T2=0 \ N=N%
510 FOR I%=1 TO N%
520 S1=S1+X(I%) \ S2=S2+X(I%)*X(I%) \ S3=S3+X(I%)*Y(I%)
530 T1=T1+Y(I%) \ T2=T2+Y(I%)*Y(I%)
540 NEXT I%
542 INPUT F$
544 PRINT E$;"\"
550 D=(N*S2)-(S1*S1)
555 A=((S3*N)-(S1*T1))/D
560 B=((S2*T1)-(S1*S3))/D
570 R=(N*S3-S1*T1)/SQR(D*((N*T2)-(T1*T1)))
580 S4=SQR(ABS((T2-T1*T1/N)/N))
590 S5=S4*SQR(ABS((1-R*R)))
640 PRINT "A=";A;" B=";B
650 PRINT "R=";R;" SE=";S5;"SDY=";S4
660 END